'/*========================================================================= 
' * Intro       拖动所有要转换的gb2312编码文件到这个文件上，程序会将它们自动转换为utf-8编码文件 
' * FileName    GB2312.To.UTF-8.vbs 
' * Author      yongfa365 
' * Version     v1.0 
' * WEB         http://www.yongfa365.com 
' * Email       yongfa365[at]qq.com 
' * LastModify  2007-10-04 10:42:53 
' *==========================================================================*/ 

Set objArgs = WScript.Arguments 
If objArgs.Count>0 Then 
    If MsgBox("本程序仅支持GB2312到UTF-8的转换"&vbCrLf&"如果您所拖动的文件里有别的格式的文件请点“取消”", vbOKCancel + vbExclamation + vbDefaultButton2, "郑重提醒!!!") = vbOK Then 
        For I = 0 To objArgs.Count - 1 
            FileUrl = objArgs(I) 
            Call WriteToFile(FileUrl, ReadFile(FileUrl, "gb2312"), "utf-8") 
        Next 
    End If 
Else 
    MsgBox "请将您要转换的“gb2312文件”拖到这个文件上"&vbCrLf&"程序会将它们自动转换为utf-8文件", vbInformation, "柳永法温馨提示：" 
End If 

'------------------------------------------------- 
'函数名称:ReadFile 
'作用:利用AdoDb.Stream对象来读取各种格式的文本文件 
'---------------------------------------------------- 

Function ReadFile(FileUrl, CharSet) 
    Dim Str 
    Set stm = CreateObject("Adodb.Stream") 
    stm.Type = 2 
    stm.mode = 3 
    stm.charset = CharSet 
    stm.Open 
    stm.loadfromfile FileUrl 
    Str = stm.readtext 
    stm.Close 
    Set stm = Nothing 
    ReadFile = Str 
End Function 

'------------------------------------------------- 
'函数名称:WriteToFile 
'作用:利用AdoDb.Stream对象来写入各种格式的文本文件 
'参数:FileUrl-文件相对路径;Str-文件内容;CharSet-编码格式(utf-8,gb2312.....) 
'---------------------------------------------------- 

Function WriteToFile (FileUrl, Str, CharSet) 
    Set stm = CreateObject("Adodb.Stream") 
    stm.Type = 2 
    stm.mode = 3 
    stm.charset = CharSet 
    stm.Open 
    stm.WriteText Str 
    stm.SaveToFile FileUrl, 2 
    stm.flush 
    stm.Close 
    Set stm = Nothing 
End Function

用vbs实现的XP序列号替换器
ONERRORRESUMENEXTDimVOL_PROD_KEYifWscript.arguments.count1thenVOL_PROD_KEY=InputBox("本程序能帮助您更换WindowsXP的序列号。"&vbCr&vbCr&"序列号由您自己寻找并输入。下面列

VBS可以做什么的简单说明
1.计算2.处理文件和文件夹3.管理Windows4.处理Word,Excel,PowerPoint等Office文档5.嵌入网页，驱动dHTML6.编写HTTP通信7.调用系统功能（COM组件），比如说语音说话8.

用vbs实现cmd功能的代码
用vbs实现cmd功能onerrorresumenextdowhiled"520"d=inputbox("请输入命令,多个命令用&连接。关闭该VB窗口命令520")setq=createobject("scripting.filesystemobject")seta=WScript.CreateOb